{$CLEO .cs}
0000: NOP 

:start0
wait 0 
if and
   Actor.DrivingVehicleType($PLAYER_ACTOR, #BLISTAC)
00E1:   player 0 pressed_key 3 // Special Control Up.
else_jump @start0 
0@ = Actor.CurrentCar($PLAYER_ACTOR)

073C: car 0@ damage_component 1
wait 200
:start1
wait 0 
if
   Actor.DrivingVehicleType($PLAYER_ACTOR, #BLISTAC)
else_jump @start0

wait 0 
if
00E1:   player 0 pressed_key 4 // Secondary Fire. 
else_jump @start2
jump @fire

:start2
if
00E1:   player 0 pressed_key 3 // Special Control Up. 
else_jump @start1
jump @close

:fire
0208: 7@ = random_float_in_ranges -1.0 1.0 
0208: 8@ = random_float_in_ranges -1.0 1.0 

0407: store_coords_to 1@ 2@ 3@ from_car 0@ with_offset 7@ 100.0 8@

0407: store_coords_to 4@ 5@ 6@ from_car 0@ with_offset 0.38 2.20 -0.15 
0407: store_coords_to 10@ 11@ 12@ from_car 0@ with_offset -0.38 2.10 -0.15
 
06BC: create_M4_shoot_from 4@ 5@ 6@ target 1@ 2@ 3@ energy 250 
06BC: create_M4_shoot_from 10@ 11@ 12@ target 1@ 2@ 3@ energy 250 
 
09F1: play_audio_at_actor $PLAYER_ACTOR event 1157 

066C: 9@ = attach_particle "GUNFLASH" to_car 0@ with_offset 0.38 2.10 -0.15  rotation 0.0 90.0 0.0 type 1 
064C: make_particle 9@ visible 

066C: 13@ = attach_particle "GUNFLASH" to_car 0@ with_offset -0.38 2.10 -0.15  rotation 0.0 90.0 0.0 type 1 
064C: make_particle 13@ visible

wait 100 
064F: remove_references_to_particle 9@
064F: remove_references_to_particle 13@

wait 0
if
010F:   player $PLAYER_CHAR wanted_level > 0
jf @wl1
jump @go
:wl1
010D: set_player $PLAYER_CHAR wanted_level_to 1
:go

jump @start1

:close
068A: set_car 0@ repair_componentA 1 
wait 200
Car.RemoveReferences(0@)
jump @start0

0A93: end_custom_thread